#include "colors.inc"
 #include "math.inc"
 #include "rand.inc"
 #include "rhombic_dodecahedron.povi"
 
 global_settings{ ambient_light White }
 background { color White }
 
 #declare LX = 50;
 #declare LZ = 100;
 light_source { <LX,-LX,LZ> color White}
 light_source { <-LX,LX,LZ> color White}
 light_source { <LX,LX,LZ> color White}
 light_source { <-LX,-LX,LZ> color White}
 
 #declare extent = 2 ;
 #declare i = -extent;
 #while ( i <= extent )
     #declare j = -extent;
     #while ( j <= extent )
     #declare k = -extent;
         #while ( k <= extent )
             #if ( even(i+j+k) & ( i+j+2*k<3*extent ) & Prob(0.95, RdmD))
                 #declare RCOLOUR = rgb < Rand_Normal( 0.6, 0.2, RdmA ) ,
                             Rand_Normal( 0.6, 0.2, RdmB ) ,
                             Rand_Normal( 0.6, 0.2, RdmC ) > ; 
                 object { rhombdod
                     scale 0.48
                     translate < i, j, k >
                     texture {
                         pigment { color RCOLOUR }
                         finish { ambient 0.3 diffuse 0.3 phong Rand_Normal( 0.5, 0.2, RdmC ) }
                         }
                     }
             #end // if
             #declare k = k+1;
         #end // while k
         #declare j = j+1;
     #end // while j
     #declare i = i+1;
 #end // while i
 
 camera {
     location 20*y
     direction -y
     right 0.4*x
     up 0.4*z
     rotate 20*x
     rotate -10*z
     }