rs[t_] := {-(E^(-2500 t^2)/(150 Sqrt[\[Pi]])) + t/3 - 1/3 t Erf[50 t],
    0, 0};
c = 1;
q = -1;
\[Beta][t_] := {(1 - Erf[50 t])/3, 0, 0};
d\[Beta][t_] := Chop@Evaluate@D[\[Beta][t1], t1] /. t1 -> t;

Plot[(\[Beta][t])[[1]], {t, -0.1, 0.1}, PlotRange -> All]
Plot[(d\[Beta][t])[[1]], {t, -0.1, 0.1}, PlotRange -> All]
\[Gamma][t_] := 1/Sqrt[1 - Norm[\[Beta][t]]^2];
n[r_, t_] := (r - rs[t])/Norm[r - rs[t]];
tr[r_, t_] := t - Norm[r - rs[t]]/c;
Ef[r_, t_] := (q (n[r, t] - \[Beta][t])/(\[Gamma][
      t]^2 (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]^2) + 
   q n[r, t] \[Cross]((n[r, t] - \[Beta][t])\[Cross]d\[Beta][t])/(
    c (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]) )
\[Tau] = 0.75;
StreamPlot[
 Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]], {x, -1, 1}, {y, -1, 
  1}, VectorPoints -> 20]
Bf[r_, t_] := (q (
    c (\[Beta][t]\[Cross]n[r, t]))/(\[Gamma][
      t]^2 (1 - n[r, t].\[Beta][t])^3 Norm[r - rs[t]]^2) + 
   q n[r, t] \[Cross](n[r, 
        t]\[Cross]((n[r, t] - \[Beta][t])\[Cross]d\[Beta][t]))/((1 - 
       n[r, t].\[Beta][t])^3 Norm[r - rs[t]]) )
S[r_, t_] := Ef[r, t]\[Cross]Bf[r, t]

p1 = Table[
   StreamDensityPlot[{Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]], 
     Log@Norm@Ef[{x, y, 0}, tr[{x, y, 0}, \[Tau]]][[1 ;; 2]]}, {x, -2,
      1}, {y, -1, 1}, ColorFunction -> "SunsetColors", 
    StreamPoints -> Medium, StreamStyle -> {White}, PlotRange -> All, 
    Frame -> False, MaxRecursion -> 5, AspectRatio -> 2/3]
   , {\[Tau], -2.5, 1.5, 0.05}];

ListAnimate[p1]

Io, detentore del copyright su quest'opera, dichiaro di pubblicarla con la seguente licenza:

Questo file è reso disponibile nei termini della licenza Creative Commons CC0 1.0 Universal.

La persona che ha associato un'opera con questo atto legale ha donato tale opera nel pubblico dominio rinunciando a tutti i diritti sull'opera in tutto il mondo, inclusi tutti i diritti connessi o altri diritti simili, per quanto permesso dalla legge. Puoi copiare, modificare, distribuire ed utilizzare l'opera, anche a fini commerciali, senza chiedere alcun permesso. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse

Il presente file, originariamente pubblicato su https://twitter.com/j_bertolotti/status/1056921689643249666, in data 30 ottobre 2018 fu esaminato dall’amministratore o dal revisore Ronhjones, il quale conferma che alla data suddetta l’immagine era disponibile a tale URL sotto la licenza citata.